;|~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~|
| D2EC: AutoCAD'de teker teker seçilen Dimension değerleri Excel tablosuna   |
|       aktarılır. Başlangıçta bir Excel Uygulaması açık ise, yeni bir       |
|       Çalışma Sayfası oluşturularak, Ölçü Değerleri aşağı doğru (sütun     |
|       düzeninde) Excel tablosuna yazılarak devam edilir. Excel uygulaması  |
|       açık değilse, yeni bir uygulama açılarak aynı işlemler yapılır.      |
|       Ondalık Basamak Ayracı ve Basamak Sayısı seçilen Dimension           |
|       nesnesinden alınarak Excel hücresine "Genel" biçimiyle yazılır.      |
|        M. Şahin Güvercin (ProhibiT) www.cizimokulu.com  10.05.2022         |
|--------___________________________________________________________---------|;
(defun c:D2EC (/ *error* ExLApp ExLLs ssT oLc dSu sTr sTn NwBk sHt1)
  (defun *error* (er/)
    (if (member er '("Function cancelled" "quit / exit abort"))
      (princ (strcat "\n\t*error*" er)))
    (if ExLLs (progn (vlax-release-object ExLLs)) (setq ExLLs nil))
    (if ExLApp (progn (vlax-release-object ExLApp) (setq ExLApp nil) (gc) (gc)))
    (if ssT (foreach n (ssnamex ssT) (redraw (cadr n) 4)))
    (if odz (setvar "dimzin" odz)) (if ocmd (setvar "cmdecho" ocmd)) (prin1))
  (vl-load-com) (setq ocmd (getvar "cmdecho") odz (getvar "dimzin"))
  (setvar "cmdecho" 0) (setvar "dimzin" 0)
  (setq ExLApp (vlax-get-or-create-object "Excel.Application"))
  (if (setq NwBk (vlax-get-property ExLApp "ActiveWorkbook"))
    (setq sHt1 (vlax-invoke-method (vlax-get-property NwBk "Sheets") "Add"))
    (setq NwBk (vlax-invoke-method (vlax-get-property ExLApp "Workbooks") "Add")
          sHt1 (vlax-get-property (vlax-get-property NwBk "Sheets") "Item" 1)))
  (setq ExLLs (vlax-get-property sHt1 "Cells")
        sTr   (vlax-get-property ExLLs 'Row)
        sTn   (vlax-get-property ExLLs 'Column))
  (princ "\nExcel'e aktarılacak Dimension Nesneleri seçiniz: ")
  (while (setq oLc (ssget ":s" (list (cons 0 "Dimension"))))
    (ssadd (setq oLc (ssname oLc 0)) (if (not ssT) (setq ssT (ssadd)) ssT))
    (redraw oLc 3) (setq oLc (vlax-ename->vla-object oLc))
    (if (not dSu) (progn (setq dSu T)
        (vlax-put-property ExLApp "UseSystemSeparators" :vlax-false)
        (vlax-put-property ExLApp "DecimalSeparator"
          (vlax-get-property oLc 'DecimalSeparator))))
    (setq oLc (rtos (if (= (vlax-get-property oLc 'Measurement) "")
                      (vlax-get-property oLc 'TextOverride)
                      (vlax-get-property oLc 'Measurement))
                    (vlax-get-property oLc 'UnitsFormat)
                    (vlax-get-property oLc 'PrimaryUnitsPrecision)))
    (vlax-put-property ExLLs "Item" sTr sTn oLc) (setq sTr (1+ sTr)))
  (if ssT (foreach n (ssnamex ssT) (redraw (cadr n) 4)))
  (vla-put-visible ExLApp :vlax-true)
  (mapcar 'vlax-release-object (list ExLLs ExLApp))
  (setq ExLLs nil ExLApp nil) (gc) (gc)
  (princ "\nM. Şahin Güvercin - www.cizimokulu.com") (prin1))