;Secilen image (resim) nesnesini secilen polyline nesnenin icerisine yerlestirir.

;Image nesnesi bloksa;
(defun c:bl (/ dc pl bl bn mz my mn mx) (vl-load-com)
  (defun m1 (p1 p2 /) (vla-put-XScaleFactor bn p1) (vla-put-YScaleFactor bn p2))
  (if (setq dc (vlax-get (vlax-get-acad-object) 'activedocument)
            bl (ssget ":s" '((0 . "insert"))))
    (progn (redraw (ssname bl 0) 3)
      (if (setq pl (ssget ":s" '((0 . "lwpolyline"))))
        (progn (vla-startundomark dc)
          (setq bn (vlax-ename->vla-object (ssname bl 0))) (m1 1 1)
          (vla-getboundingbox bn 'mn 'mx)
          (vla-getboundingbox (vlax-ename->vla-object (ssname pl 0)) 'my 'mz)
          (m1 (/ (- (car (setq mz (vlax-safearray->list mz))) (car (setq my
            (vlax-safearray->list my)))) (- (car (setq mx (vlax-safearray->list mx)))
              (car (setq mn (vlax-safearray->list mn))))) (/ (- (cadr mz) (cadr my))
                (- (cadr mx) (cadr mn))))
          (vlax-invoke bn 'move mn my) (vla-endundomark dc)
        )
      ) (redraw (ssname bl 0) 4)
    )
  ) (prin1)
)


;Image nesnesi blok degilse;
(defun c:im (/ dc pl bl bn mz my) (vl-load-com)
  (if (setq dc (vlax-get (vlax-get-acad-object) 'activedocument)
            bl (ssget ":s" '((0 . "image"))))
    (progn (redraw (ssname bl 0) 3)
      (if (setq pl (ssget ":s" '((0 . "lwpolyline"))))
        (progn
          (vla-getboundingbox (setq bn (vlax-ename->vla-object (ssname bl 0))) 'mn 'mx)
          (vla-getboundingbox (vlax-ename->vla-object (ssname pl 0)) 'my 'mz)
          (vla-startundomark dc)
          (vla-put-ImageWidth bn (- (car (setq mz (vlax-safearray->list mz)))
            (car (setq my (vlax-safearray->list my)))))
          (vla-put-ImageHeight bn (- (cadr mz) (cadr my)))
          (vlax-invoke bn 'move (vlax-safearray->list mn) my) (vla-endundomark dc)
        )
      ) (redraw (ssname bl 0) 4)
    )
  ) (prin1)
)