; places name of block as text via pick

(defun C:blockn()

(setvar "cmdecho" 0)

(setq pt(cadr(entsel"\nSelect Block:")))

(setq e1(ssget pt))

(setq e2 (entget (ssname e1 0)))

(setq blname (cdr(assoc 2 e2)))

(setq pt1 (getpoint"\nSelect point for block title:"))

(command "text" pt1 "" 0 blname)

)

(defun c:TEST (/ #Entsel #InsPoint #Name #Desc #LandPoint)
(if (setq
       #Entsel (AT:Entsel nil "\nSelect block: " '((0 . "INSERT")) nil)
     ) ;_ setq
   (progn
     ;; convert to vla-object
     (setq #Entsel   (vlax-ename->vla-object (car #Entsel))
           ;; insertion point
           #InsPoint (vlax-safearray->list
                       (vlax-variant-value
                         (vla-get-InsertionPoint #Entsel)
                       ) ;_ vlax-variant-value
                     ) ;_ vlax-safearray->list
           ;; block name
           #Name     (vla-get-name #Entsel)
           ;; block description
           #Desc     (vla-get-comments
                       (vla-item
                         (vla-get-blocks
                           (vla-get-activedocument (vlax-get-acad-object))
                         ) ;_ vla-get-blocks
                         #Name
                       ) ;_ vla-item
                     ) ;_ vla-get-comments
     ) ;_ setq
     (cond
       ;; no description in block
       ((eq "" #Desc)
        (princ (strcat "\nNo description for block: ""
                       #Name
                       """
               ) ;_ strcat
        ) ;_ princ
       )
       ;; specify leader landing location
       ((setq #LandPoint
               (getpoint #InsPoint
                         "\nSpecify leader landing location: "
               ) ;_ getpoint
        ) ;_ setq
        (vl-cmdf "_.mleader" "_non" #InsPoint "_non" #LandPoint #Desc)
       )
     ) ;_ cond
   ) ;_ progn
) ;_ if
(princ)
) ;_ defun
;;; Entsel or NEntsel with options
;;; #Nested - Entsel or Nentsel (T for Nentsel, nil for Entsel)
;;; #Message - Selection message (if nil, "\nSelect object: " is used)
;;; #FilterList - DXF ssget style filtering, no cons (nil if not required)
;;; #Keywords - Keywords to match instead of object selection (nil if not required)
;;; Example: (AT:Entsel nil "\nSelect MText not on 0 layer [settings]: " '((0 . "MTEXT")(8 . "~0")) "Settings")
;;; Alan J. Thompson, 04.16.09
;;; Updated: Alan J. Thompson, 06.04.09 (changed filter coding and added layer option)
(defun AT:Entsel (#Nested     #Message    #FilterList #Keywords
                 /           #Count      #Message    #Choice
                 #Ent
                )
(setvar "errno" 0)
(setq #Count 0)
(or #Message (setq #Message "\nSelect object: "))
(if #Nested
   (setq #Choice nentsel)
   (setq #Choice entsel)
) ;_ if
(while (and (not #Ent)
             (/= (getvar "errno") 52)
        ) ;_ and
   (and #Keywords (initget #Keywords))
   (cond
     ((setq #Ent (#Choice #Message))
      (and
        #FilterList
        (vl-consp #Ent)
        (or
          (not
            (member
              nil
              (mapcar
                '(lambda (x)
                   (wcmatch
                     (if
                       (eq
                         (type
                           (cdr (assoc (car x) (entget (car #Ent))))
                         ) ;_ type
                         'STR
                       ) ;_ eq
                        (strcase
                          (cdr (assoc (car x) (entget (car #Ent))))
                        ) ;_ strcase
                        (cdr (assoc (car x) (entget (car #Ent))))
                     ) ;_ if
                     (cdr x)
                   ) ;_ wcmatch
                 ) ;_ lambda
                #FilterList
              ) ;_ mapcar
            ) ;_ member
          ) ;_ not
          (setq #Ent nil)
        ) ;_ or
      ) ;_ and
     )
   ) ;_ cond
   (and (= (getvar "errno") 7)
        (not #Ent)
        (setq #Count (1+ #Count))
        (prompt (strcat "\nNope, keep trying!  "
                        (itoa #Count)
                        " missed pick(s)."
                ) ;_ strcat
        ) ;_ prompt
   ) ;_ and
) ;_ while
#Ent
) ;_ defun

(defun c:bnw (/ blk n dat)
  (setq n 0 blk (ssget (list (cons 0 "insert"))))
  (setvar "cmdecho" 0) (command "_.undo" "be")
  (if blk (repeat (sslength blk)
    (setq dat (entget (ssname blk n)) n (1+ n))
    (entmake (list (cons 0 "text") (cons 10 (cdr (assoc 10 dat)))
      (cons 11 (cdr (assoc 10 dat))) (cons 1 (cdr (assoc 2 dat)))
      (cons 40 (getvar "textsize")) (cons 72 1) (cons 73 2)))))
  (command "_undo" "end") (setvar "cmdecho" 1) (princ)
)