(defun C:Z0 (/ olderr oldcmd ss1 ss1len i numchg numnot numno0 ssno0
                    ename elist etype yorn)
(command  "._UCS" "_Delete" "$ZSIFIR-TEMP-2$")
   (setq olderr *error*)
   (defun *error* (msg)
      (if (= msg "quit / exit abort")
         (princ)
         (princ (strcat "error: " msg))
      )
      (setq *error* olderr)
      (command "._UCS" "_Restore" "$ZSIFIR-TEMP-2$" "._UCS" "_Delete"  "$ZSIFIR-TEMP-2$")
      (command "._UNDO" "_End")
      (setvar "CMDECHO" oldcmd)
      (princ)
   )

   (setq oldcmd (getvar "CMDECHO"))
   (setvar "CMDECHO" 0)
   (command "._UNDO" "_Group")
   (command "._UCS" "_Save" "$ZSIFIR-TEMP-2$" "._UCS" "World")
         (graphscr)
         (prompt "\n Eleman seçiniz... (Z Koordinatları 0 yapılacak)...")
         (setq ss1 (ssget))
         (if (null ss1)
             (setq ss1 (ssget "X"))
         )
         (setq ss1len (sslength ss1)
               i 0
               numchg 0
               numnot 0
               numno0 0
               ssno0 (ssadd)
         )
         (while (< i ss1len)
            (if (= 0 (rem i 10)) (prompt "."))
            (setq ename (ssname ss1 i)
                  elist (entget ename)
                  etype (cdr (assoc 0 elist))
            )
;
            (if (member etype '("LINE" "POLYLINE" "TEXT" "INSERT" "CIRCLE"
                                 "ARC" "POINT" "SOLID"))
               (setq elist (zeroz 10 elist)
                     numchg (1+ numchg)
               )
               (progn
                  (setq numnot (1+ numnot))     
                  (if (/= 0.0 (car (reverse (assoc 10 elist))))
                     (progn
                        (setq numno0 (1+ numno0))
                        (ssadd ename ssno0)
                     )
                  )
               )
            )
;
;
            (if (member etype '("LINE" "TEXT" "SOLID"))
               (setq elist (zeroz 11 elist))
            )
;
            (if (member etype '("SOLID"))
               (progn
                  (setq elist (zeroz 12 elist))
                  (setq elist (zeroz 13 elist))
               )
            )
;
            (setq i (1+ i))
         )
         (prompt (strcat "\n" (itoa numchg) " entity(s) ZSIFIRed"))
         (prompt (strcat "\n" (itoa numnot) " entity(s) not ZSIFIRed"))
         (if (/= 0 numno0)
            (progn
               (prompt    (strcat "  [" (itoa numno0) " with non-zero base points]"))
               (getstring  "\nPress enter to see non-zero unchanged entities... ")
               (command    "._SELECT" ssno0)
               (getstring  "\nPress enter to unhighlight them... ")
               (command    "")
            )
         )
   (command "._UCS" "_Restore" "$ZSIFIR-TEMP-2$"
            "._UCS" "_Delete" "$ZSIFIR-TEMP-2$")
   (command "._UNDO" "_End")
   (setvar "CMDECHO" oldcmd)
   (setq *error* olderr)
   (princ)
)

(defun zeroz (key zelist / oplist nplist)
   (setq oplist (assoc key zelist)
         nplist (reverse (append '(0.0) (cdr (reverse oplist))))
         zelist (subst nplist oplist zelist)
   )
   (entmod zelist)
)
(princ)